Excel - Multi-select from a dropdown list

Asked By PaulaG on 07-Apr-10 08:34 AM
I have a dropdown list but wish to select more than one item from it - is
this possible?




Dave Peterson replied to PaulaG on 07-Apr-10 09:00 AM
Not really.

Could you replace it with a listbox -- and allow multiple selections?


--

Dave Peterson
Roger Govier replied to PaulaG on 07-Apr-10 10:03 AM
Hi Paula

Only with code

This code (not written by me) will allow you to make multiple selections
from a data validation cell, and will insert a comma between each
selected value

Private Sub Worksheet_Change(ByVal Target As Range)
Dim rngDV As Range
Dim oldVal As String, newVal As String
Dim tr As Long
tr = Target.Row
If Target.Count > 1 Then GoTo exitHandler

On Error Resume Next
Set rngDV = Cells.SpecialCells(xlCellTypeAllValidation)
On Error GoTo exitHandler

If rngDV Is Nothing Then GoTo exitHandler

If Intersect(Target, rngDV) Is Nothing Then
'do nothing
Else
Application.EnableEvents = False
newVal = Target.Value
Application.Undo
oldVal = Target.Value
Target.Value = newVal
If oldVal = "" Then
'do nothing
Else
If newVal = "" Then
'do nothing
Else
Target.Value = oldVal _
& ", " & newVal
End If
End If
End If

exitHandler:
Application.EnableEvents = True
End Sub

It is event code so you need to copy it to the sheet where you have your
cells with Data Validation.

Copy code above
Right click on sheet tab>View Code
Paste code into white pane that appears
Alt+F11 to return to Excel.

--
Regards
Roger Govier
Gord Dibben replied to PaulaG on 07-Apr-10 11:43 AM
Multiselect from a DV dropdown is possible using VBA.

See Debra Dalgleish's site for a downloadable sample workbook with event
code.

http://www.contextures.on.ca/excelfiles.html#DV0017

Note that you can have the selections in an adjacent cell or in the same
cell.


Gord Dibben  MS Excel MVP
JB replied to Dave Peterson on 07-Apr-10 01:36 PM
http://boisgontierjacques.free.fr/fichiers/DonneesValidation/DVChoixSuccessifs.xls

JB
http://boisgontierjacques.free.fr/
Dave Peterson replied to JB on 07-Apr-10 01:52 PM
I do not open unsolicited workbooks.




--

Dave Peterson